package MyAuth::TypeKey;

use strict;
use warnings;
use base qw(MyAuth);

use CGI::Application::Plugin::Redirect;

use Authen::TypeKey;
use URI;

sub setup {
    my $self = shift;

    $self->start_mode('default');
    $self->run_modes(
        default => 'default',
        verify  => 'verify',
        logout  => 'logout',
    );

    my $api = Authen::TypeKey->new;
    $api->token('xxxxxxxxxxxxxxxxxxxxxxxx');
    $self->stash->{api} = $api;

    $self->stash->{apiname}   = 'Authen::TypeKey';
    $self->stash->{login_uri} = $self->_create_login_uri($api);
}

sub default {
    my $self = shift;
    $self->tt_process('index.tt');
}

sub _create_login_uri {
    my ($self, $api) = @_;

    ## callback uri
    my $cb_uri = URI->new($self->query->url . '/verify');

    return "https://www.typekey.com/t/typekey/login?lang=ja&v=1.1&t=".$api->token."&_return=$cb_uri&need_email=1";
}

sub _process_verify {
    my $self = shift;

    my $api = $self->stash->{api};
    my $res = $api->verify($self->query) or die $api->errstr;

    return {
        name  => $res->{name},
        nick  => $res->{nick},
        email => $res->{email},
        ts    => $res->{ts},
    };
}

1;